title	setup
	search	monsym

t1	__ 1
t2	__ 2
t3	__ 3
t4	__ 4
p	__ 17

st:	move	p,[iowd 10,pdl]
	movei	1,.fhslf
	rpcap
	trnn	2,sc%whl+sc%opr
	 haltf
	move	3,2
	epcap

	gjinf
	movem	1, unum

	setom	rnublk+.msrch	;step thru all units
	setom	rnublk+.msrct
	setom	rnublk+.msrun

lp:	hrroi	t1,nambuf	;place for name
	movem	t1,rnublk+.msrsn
	hrroi	t1,alibuf	;alias
	movem	t1,rnublk+.msrsa
	move	t1,[.msrln,,.msrnu] ;get stuff about next unit
	movei	t2,rnublk
	mstr
	  erjmp	rnuerr

	skipl	rnublk+.msrst	;mounted?
	  jrst	lp		;no, skip it

	ldb	t1,[point 9,rnublk+.msrst,17] ;ms%typ
;;	caig	t1,.msrp6	;rp04, ro05, rp06?
;;	  jrst	lp		;yes, don't bother its user by mounting it
;;.msr20==24
;;	caile	t1,.msr20	;CFS disk?
;;	  jrst	lp		; yes, don't get HUNG!!

	hrroi	t1,alibuf
	psout

	hrroi	t1,alibuf	;point to alias
	movem	t1,imcblk
	move	t1,[1,,.msimc]	;mount the str
	movei	t2,imcblk
	mstr
	  ercal	imcerr

	hrroi	t1, [asciz ':	mounted']
	psout

	move	t2, [point 7, alibuf]
	move	t1, [point 7, accbuf]
l1:	ildb	t3, t2
	jumpe	t3, x1
	idpb	t3, t1
	jrst	l1

x1:	movei	t3, ":"
	idpb	t3, t1
	movei	t3, "<"
	idpb	t3, t1

	move	t2, unum
	dirst
	 erjmp	lp

	movei	t3, ">"
	idpb	t3, t1
	setz	t3,
	idpb	t3, t1

	hrroi	t1, accbuf
	movem	t1, accblk+.acdir
	setzm	accblk+.acpsw
	setom	accblk+.acjob

	move	t1, [ac%own!3]
	movei	t2, accblk
	acces
	 erjmp	lp0

	hrroi	t1, [asciz ', accessed']
	psout
;	hrroi	t1, accbuf
;	psout
lp0:	hrroi	t1, [asciz /
/]
	psout
	jrst	lp		;do them all

rnuerr:	movei	t1,.fhslf	;get the error
	geter
	hrrz	t1,t2
	caie	t1,mstx18	;no more units?
	  pushj	p,jse		;other err, type error message
	haltf			;yes, done

imcerr:	movei	t1,.fhslf	;get error
	geter
	hrrz	t1,t2
	caie	t1,mstx31	;already mounted?
	  pushj	p,jse		;no, complain
	popj	p,		;yes, ignore

jse:	hrroi	t1,alibuf
	psout
	hrroi	t1,[asciz /: /]
	psout
	movei	t1,.priou
	hrloi	t2,.fhslf
	setz	t3,
	erstr
	  jfcl
	  jfcl
	hrroi	t1,[asciz /
/]
	psout
	popj	p,

rnublk:	block	.msrln
imcblk:	block	1
alibuf:	block	10
nambuf:	block	10
accbuf:	block	20
accblk:	block	3	
unum:	block	1
pdl:	block	10

	end	st