TITLE WEB	PROGRAM TO CATCH SPIDERS
 
	SEARCH MONSYM,MACSYM
	.REQUIRE SYS:MACREL
	SALL
 
	T1==1
	T2==2
	T3==3
	T4==4
	T5==5
	P==17
 
PDL:	BLOCK <PDLSIZ==20>
BUFFER:	BLOCK 200
 
ST:	RESET
	MOVE P,[IOWD PDLSIZ,PDL]
	MOVEI T1,.FHSLF
	RPCAP
	TXO T3,SC%WHL!SC%OPR
	EPCAP
	MOVEI T1,.SNPSY
	MOVE T2,[RADIX50 0,TTACTL]
	MOVE T3,[RADIX50 0,STG]
	SNOOP
	 JSHLT
	HRLI T2,1
	MOVEM T2,TTACTL#
	MOVE T2,[RADIX50 0,TTLINK]
	MOVE T3,[RADIX50 0,TTYSRV]
	SNOOP
	 JSHLT
	HRLI T2,1
	MOVEM T2,TTLINK#
	GJINF
	JUMPL T4,[HALTF
		 JRST ST]
	MOVEM T4,MYTTY#
	MOVE T1,TTACTL
	ADDI T1,0(T4)
	MOVEI T2,T4
	PEEK
	 JSHLT
	MOVE T1,TTLINK
	ADDI T1,0(T4)
	MOVEI T2,T4
	PEEK
	 JSHLT
	CAMN T4,[-1]
	 JRST [HALTF
	       JRST ST]
	MOVE T5,[POINT 9,T4]
	HRROI T1,BUFFER
	FMSG <You are linked to TTY>
 
LOOP:	ILDB T2,T5
	CAIN T2,777
	 JRST LOOP
	JRST LOOP2
 
LOOP1:	ILDB T2,T5
	CAIN T2,777
	 JRST ELOOP
	FMSG <              and TTY>
	LDB T2,T5
LOOP2:	MOVEI T3,10
	NOUT
	 JSHLT
	PUSH P,T2
	FMSG <:, user >
	EXCH T1,0(P)
	MOVEI T1,400000(T1)
	HRROI T2,T3
	MOVEI T3,.JIUNO
	GETJI
	 JRST UNKNOW
	CAIN T3,0
	 JRST [POP P,T1
	       FMSG <not logged in
>
	       JRST ELOOP]
	MOVE T1,0(P)
	MOVE T2,T3
	DIRST
UNKNOW:	 JRST [POP P,T1
	       FMSG <unknown
>
	       JRST ELOOP]
	ADJSP P,-1
	FMSG <
>
 
ELOOP:	TLNE T5,770000
	 JRST LOOP1
	SETZ T2,
	IDPB T2,T1
	MOVE T1,MYTTY
	ADDI T1,400000
	HRROI T2,BUFFER
	TTMSG
	HALTF
	JRST ST
 
	END ST