/DECIMAL PRINT ROUTINE
/JOHN WILSON 10-JUN-84
/PRINTS NUMBER IN AC
PRDEC,	0
	DCA NUM		/SAVE THE NUMBER
	DCA NUMTXT	/CLEAR CHAR CNT
	TAD (NUMEND	/POINT AT END OF STRING
	DCA NUMTXT+1
PRDEC1,	TAD NUM		/GET NUMBER
	DCA CHAR	/SAVE IN CHAR
	DCA NUM		/CLEAR NUMBER
	TAD CHAR	/GET NUMBER BACK
PRDEC2,	CLL		/CLEAR LINK
	TAD (-12	/SUBTRACT 10.
	SNL		/SKIP IF NO BORROW
	JMP PRDEC3	/OTHERWISE JUMP OUT OF DIVISION
	DCA CHAR	/UPDATE CHAR
	ISZ NUM		/UPDATE QUOTIENT
	TAD CHAR	/GET CHAR BACK
	JMP PRDEC2	/LOOP
PRDEC3,	CLA
	TAD CHAR	/GET AND PRINT CHAR, FOR NOW
	TAD ("0		/CONVERT TO ASCII
	DCA I NUMTXT+1	/PUT CHAR IN BUFF
	STA		/DEC PTR
	TAD NUMTXT+1
	DCA NUMTXT+1
	ISZ NUMTXT	/INC CTR (NEGATE LATER)
	TAD NUM		/ANYTHING LEFT?
	SZA CLA		/NO, EXIT
	JMP PRDEC1	/YES, PRINT IT TOO
	TAD NUMTXT	/NEGATE CHAR CNT
	CIA
	DCA NUMTXT	/REPLACE IT
	TAD (NUMTXT	/PRINT THE NUMBER
	SAS
	JMP .-2		/LOOP UNTIL ALL PUT IN TTY BUFF
	JMP I PRDEC	/RETURN
NUM,	0	/HOLDS NUMBER, AND QUOTIENT DURING DIVISION
CHAR,	0	/HOLDS REMAINDER FROM DIVISION (CHARACTER)
NUMTXT,	0	/LENGTH OF NUMBER
	0	/PTR TO BEGN OF NUMBER TEXT
	0	/ALLOW 4 DIGITS FOR NUMBER
	0
	0
NUMEND,	0	/LAST DIGIT
$