         SYSTEM   UTS
         DEF      T:ACCTEX
*
         REF      J:CTIME
         REF      J:DELTAT
         REF      J:OVHTIM
         REF      J:PTIME
         REF      J:RNST
         REF      J:UTIME
         REF      UB:PCT
         REF      J:MRT
         REF      J:ASSIGN
         REF      S:CUN
         REF      UH:FLG
         REF      T:TELDELCCI
         REF      J:UTIMER
         REF,1    JB:PNR
         REF      SL:QUAN
         REF      PLH:QN
         REF      J:IDELTAT
*
         DEF      ACCT
         DEF      ACCTSIZ
ACCT     EQU      %
PMONOFF EQU 1
         PAGE
T:ACCTEX EQU      %
         LW,1     S:CUN
         LCW,7    SL:QUAN
         LC       J:JIT
         BCS,12   %+4
         LI,5     BA(JB:PNR)
         LB,5     0,5
         LCH,7    PLH:QN,5
         LCW,10   J:IDELTAT
         AW,10    J:DELTAT
         STW,7    J:DELTAT
         STW,7    J:IDELTAT
         LW,5     10
         AW,5     J:OVHTIM
         LI,11    0
         STW,11   J:CTIME
         XW,11    J:OVHTIM
         LB,7     UB:PCT,1
         MW,7     5
         LH,4     J:RNST
         AND,4    X10
         BNEZ     1A1
         AWM,10   J:PTIME
         AWM,11   J:PTIME+1
         AWM,7    J:PTIME+2
         B        1A2
1A1      AWM,10   J:UTIME
         AWM,11   J:UTIME+1
         AWM,7    J:UTIME+2
1A2      LCW,7    5
         AWM,7    J:UTIMER
         LW,4     J:MRT
         BEZ      ACCT1
         AWM,7    J:MRT
         BGZ      ACCT1
         LI,7     0
         STW,7    J:MRT             DONT MAX HIM MORE THAN ONCE
         LI,7     X'80'
         STS,7    J:ASSIGN          SET MAX TIME FLAG
         LI,7     4
         STB,7    J:RNST            SET MAX SOMETHING RUN STATUS
ACCT1    RES      0
         DO       PMONOFF=1
         REF      PMSCA,C:MSB,C:MSO
         BAL,4    PMSCA
         FIN
         LC       J:JIT
         BCS,4    PMSCOUT
         LI,4     C:SCO
         BCS,8    %+2
         LI,4     C:SCB
         AWM,5    0,4
         DO       PMONOFF=1
         AWM,11   C:MSB-C:SCB,4
         AI,2     0
         BEZ      %+2
         AWM,5    *2,4
         FIN
PMSCOUT  B        0,3
         REF      J:JIT,C:SCB,C:SCO
ACCTSIZ  EQU      %-ACCT
         END

