         DEF      ADD
ADD      EQU      %
         REF      Y04,Y4
         SYSTEM   UTS
OC       EQU      2
R0       EQU      0
R1       EQU      1
R2       EQU      2
R3       EQU      3
R4       EQU      4
R5       EQU      5
R6       EQU      6
R7       EQU      7
SR1      EQU      8
SR2      EQU      9
SR3      EQU      10
SR4      EQU      11
D1       EQU      12
D2       EQU      13
D3       EQU      14
D4       EQU      15
         PAGE
*        BAL,11   GETI              FROM COOP
*        USES  R1,R5,R14,R15
*        RETURN SR1=DA
*GET SELECTED JOB FROM GETI TABLES AND SET
*UP THE JIT -- ENTRY FOUND WHEN S:CUN=GIB:UN -- MBS
*HAS PUT INFO IN TABLES AND STARTED JOB -- GI:FRE IS
*THE FREE ENTRY CHAIN
         SPACE 2
         DEF      GETI
GETI     EQU      %
         LW,R1    S:CUN
         LI,R5    3
         CB,R1    GIB:UN,R5
         BE       GETI1
         BDR,R5   %-2
GETIX    EQU      %
         SCREECH  X'2C',0
*            BATCH COMMAND PROCESSOR ERROR
*        OR, SCHEDULING ERROR(NEW BATCH USER W/O MBS)
*        OR, MBS/GETI COMMUNICATION PROBLEM.
GETI1    EQU      %
         LI,D3    0
         STB,D3   GIB:UN,R5
         LH,D4    GIH:TIM,R5
         MI,D3    30000
         STW,D4   J:MRT
*
         REF      PRT,GIB:PRI
         LB,D3    GIB:PRI,R5
         LI,D4    X'F'
         SLD,D3   20
         STS,D3   J:JIT+PRT         STORE PRIO IN JIT
*
*                 NEW GERM INFO
         REF      JB:MAX
         LW,D4    5
         SLS,D4   1
         AW,D4    5                 (5)*3
         AI,D4    GI:ASPN-1
*
         LI,1     3
         LW,D3    *D4,1
         STW,D3   J:ASPIN-1,1
         BDR,1    %-2
*
         LI,1     4
         LW,D4    5
         SLS,D4   2
*                 (5)*4
         AI,D4    GI:RES-1
         LW,D3    *D4,1
         STW,D3   JB:MAX-1,1
         BDR,1    %-2
*
         SPACE 4
         LB,D3    GIB:SLN,R5
         LI,R1    JB:SLNK
         STB,D3   0,R1
         LB,D3    GIB:XLN,R5
*                 SET UP EXCULSIVE BATCH LIST OF SERIAL #'S
         REF      PLB:MIN,SV:RSIZ
*
*
         LB,R1    GIB:PRT,5
         MI,R1    SV:RSIZ+1
         STB,D3   PLB:MIN,R1       SAVE IT
*
*
         LI,R1    JB:XLNK
         STB,D3   0,R1
         LI,R1    1
         LB,D3    GIB:RID,R5
         BEZ      %+2
         MTB,2    JB:ORG,R1
         STB,D3   JRBID+J:JIT,R1
         LI,SR1   0
         XW,SR1   GI:SDA,R5
         CW,SR1   Y01
         BAZ      %+2
         MTB,1    JB:ORG,R1
         CW,SR1   Y04
         BAZ      GETI2
         LW,R1    SR3
         LW,D4    Y4
         STS,D4   1,R1    RABBIT SAID RE-RUN
GETI2    RES      0
         AND,SR1  M24
         LB,R1    GIB:PRT,R5
         DISABLE
         XW,R5    GI:FRE
         SLS,R5   8
         AWM,R5   GI:FRE
         ENABLE
         LI,R5    JB:PNR
         STB,R1   0,R5
         LH,D4    PLH:SID,R1
         LI,R5    1
         STH,D4   J:JIT,R5
         STB,5    JB:MAX            SET K (NOT PAGES) FLAG
         B        *SR4
*
*
*        REFS FOR GETI         *
*
         REF      M24,S:CUN,PLH:SID
         REF      GI:FRE
         REF      GI:SDA,GI:RES,GI:ASPN
         REF      GIH:TIM
         REF      GIB:RID,GIB:SLN,GIB:XLN,GIB:PRT,GIB:UN
         REF      J:JIT,JRBID,J:ASPIN,J:MRT
         REF      JB:ORG   (WORD ADDRESS)
         REF,1    JB:SLNK,JB:XLNK,JB:PNR
*
*
*    ROUTINES IN THIS MODULE ARE ONLY CALLED
*    FROM OPNLD IN MUL, THUS IT CAN GO NON RESIDENT
*    TO THAT OVERLAY GIVEN A LOCCT CHANGE.
*
         REF      Y01               *=X'01000000'
*
*
          END

