         SYSTEM   SIG7P
         SYSTEM   BPM
CNM      EQU      1                 FOR TP AND CNM
         TITLE    ' RECOVER2 -- RESTORE DATA REMEMBERED BY RECOVER'
R0       EQU      0
R1       EQU      1
R2       EQU      2
R3       EQU      3
R4       EQU      4
R5       EQU      5
R6       EQU      6
R7       EQU      7
SR1      EQU      8
SR2      EQU      9
SR3      EQU      10
SR4      EQU      11
D1       EQU      12
D2       EQU      13
D3       EQU      14
D4       EQU      15
         PAGE
         PCC      0
PUSH     CNAME    X'0B'
PULL     CNAME    X'0A'
         PROC
LF       EQU      %
TMP      SET      -2
         DO       NUM(AF)>1
         DO       AF(1)<16
         LCI      AF(1)
         ELSE
         LCI      0
         FIN
TMP      SET      0
         FIN
         GEN,8,4,20 NAME+TMP,AF(NUM(AF)),R:TSTACK
         PEND
         PAGE
         REF      RCVRGFC,SGCHD
         REF      SGB
         REF      JACCN
         REF      RCVRAD,RCVRCNT
         REF      DCT1,DCT4
         REF      CHKDA,JIT,J:AMR
         REF      R:TSTACK,RDRAD1
         REF      75BUF
         REF      RDDISK1,RBG,HGP
         REF      NCYL,NTPC,NSPT
         REF      DCT22
         REF      CYL%SHFT,TRK%SHFT,SEC%SHFT
         REF      DISCLIMS
         REF      NSPC
         SREF     COC
         SREF     COCMESS
         SREF     LCOC
         REF      M:XX,M:EI
         REF      RECORD,RATEFLAG,ACCNTSUM
         REF      M:EO
         REF      TSTACK
         REF      SSIG
         REF      S:DP
         REF      RDUSR1
         REF      WRDISK1
         SREF     UB:C#
         REF      RCVCODE
         SREF     COD:LPC,COCTERM,COCOTV,MODE2,CO:STAT
         DEF      MAPFLG
         DEF      R:HGP,R:DCT1,R:DCT4
         DEF      R:DCT22
         DEF      R:NCYL,R:NTPC,R:NSPT
         DEF      R:CYL%SHFT,R:TRK%SHFT,R:SEC%SHFT
         DEF      R:DISCLIMS
         DEF      R:NSPC
R:HGP    EQU      HGP
R:DCT1   EQU      DCT1
R:DCT22  EQU      DCT22
R:NCYL   EQU      NCYL
R:NTPC   EQU      NTPC
R:NSPT   EQU      NSPT
R:CYL%SHFT EQU    CYL%SHFT
R:TRK%SHFT EQU    TRK%SHFT
R:SEC%SHFT EQU    SEC%SHFT
R:DISCLIMS EQU    DISCLIMS
R:NSPC   EQU      NSPC
R:DCT4   EQU      DCT4
MONDMP   EQU      M:XX
         DEF      P:JIT
RECOVER2 DSECT    0
         STW,11   RCVXT
         LW,11    RCVRAD            SAVE RCVRAD
         STW,11   TMP1
         CAL1,8   GET:CM
         BCS,8    NORCV
         AI,9     512+511           LAST L0C IN BUF
         STW,9    BUFLN
         LW,8     RCVRAD            SAVE RCVRAD ADDRESSES
         LI,3     512*4                 TO LOCATE RECOVERY BUFFER
         LW,4     BUFLN
         AI,4     -1023
         BAL,11   RDDISK1
         B        NORCV             ERR RETURN
         BAL,11   INCRDA            INCREMENT TO NEXT PAGE
         LI,3     512*4
         LW,4     BUFLN
         AI,4     -511
         LW,8     RCVRAD
         BAL,11   RDDISK1           READ SECOND HALF OF BUFFER
         B        NORCV             ERROR RETURN
         LI,R4    RECOVER2
         BAL,SR4  WRDISK1           GO-CLOBBER RECOVER BUF ON SWAPER
         B        NORCV
         MTW,0    75BUF             ANY ERRORS REPORTED FROM FOX
         BGEZ     KRD50             NO
         LI,R4    HGPERRUM          YES-TELL USERS
         BAL,SR4  COCOUT            ON THERE TTYS
         B        %                 OPERATOR MUST REBOOT
KRD50    EQU      %
         LB,1     *BUFLN
         CI,1     4                 CHECK SV CODE
         BNE      NORCV             NO RECOVERY POSSIBLE
         BAL,11   INCRDA            SET RCVRAD TO START OF CORE DUMP
         LI,R5    7
         AND,R5   RCVRCNT           RECOVER COUNT MOD 8
         STS,R5   DMPNAME+1         PUT INTO FILE NAME
         LI,2     -1                POINTER TO CURRENT WORD
         MTB,0    X'2A'             RECOVERY FROM CRASH
         BEZ      PROCBUF           YES
         LW,3     *BUFLN,2          'ZAP' CODE WORD
         LI,2     -2                POINT TO NEXT CODE WORD
         CI,3     X'40404'          BOOT AFTER 'ZAP'
         BNE      EXIT              NO-TAKE ERROR RETURN
         LW,R5    =X'01010002'
         STW,R5   DMPNAME-1         PREVENT MONDMP OPEN FOR ZAP CASE
PROCBUF  LW,3    *BUFLN,2           PROCESS BUFFER
         LI,1     1
         LB,4     3                 FETCH SV CODE
         BEZ      NORCV
         CI,4     MAX               MAX ASSIGNED COMPUTER
         BGE      NORCV
         MTB,0    X'2A'             IF NO CRASH, DO LIMOTED RECOVERY
         BEZ      %+2
         LB,4     CODECODE,4
MAXST    EQU      %
         B        %,4
         B        SKIP              SV CODE =1     ERROR LOG (FOX)
         B        COCMES                    =2     COC MESSAGE
         B        RCVDMP                    =3    RECOVERY DUMP
         B        RETURN-1        NO        =4    SIZE OF BUFFER
         B        TPDMP                     =5    DUMP TAPE
         B        SKIP                      =6     DOWN DEVICE LIST (FOX)
         B        SYMFR                     =7    SYMFILES
         B        ACT                       =8    JITS FOR ACCOUNTING
         B        SKIP                      =9     SYSTEM LIMITS (FOX)
         B        SKIP                      =A    **UNUSED**
         B        SKIP                      =B     HGP RECONSTRUCTION (FOX)
         B        SKIP                      =C    **UNUSED**
         B        SKIP                      =D     RELEASE GRANULES (FOX)
         B        SKIP              =E  **UNUSED**
         B        SKIP                      =F     RBBAT DATA (FOX)
         B        SGCBUF            =10 WRITE SG COMM BUFFER TO :SYS
         B        SKIP                      =11    RBBAT ERROR (FOX)
         DO1      CNM
         B        COCRES            =12 COC TABLES RMC  TP
MAX      EQU      %-MAXST
SK       EQU      SKIP-MAXST
CODECODE DATA,1   SK,1,SK,SK,SK,SK,6,7,SK,9,SK,SK,SK,13,14,15,16,17
         DO1      CNM
         DATA,1   SK                RMC 4-17-74 TP
         BOUND    4
SKIP     SH,2     3,1               IGNORE THIS ENTRY
         AI,2     -1
RETURN   LI,3     X'FFFF'           RETURN FROM PROCESSORS
         LS,3    *BUFLN
         AW,3     2
         BGZ      PROCBUF
         MTB,0    X'2A'             IF NO CRASH WE ARE DONE
         BNEZ     EXIT
         MTW,1    RCVXT             NO - EXIT SKIPPING
EXIT     EQU      %
         LW,3     TMP1              RESTORE RCVRAD
         STW,3    RCVRAD
         B        *RCVXT
         PAGE
NORCV    EQU      %
         MTB,0    X'2A'             IF NO CRASH, DONT WORRY
         BNEZ     EXIT              EXIT
         LI,4     HGPERRUM          TELL USERS RECOVERY IMPOSSIBLE
         BAL,11   COCOUT
         M:MESSAGE (MESS,MSG)       RECOVERY TABLE CLOBBERED
         LW,4     BUFLN
         AI,4     -1023
         STW,4    TMP1
         M:SNAP   'RCVBUFF',(*TMP1,*BUFLN) SNAP BUFFER
         M:MESSAGE (MESS,MSG1)      REBOOT RAD
         B        %
MSG      TEXTC    'RECOVERY TABLES CLOBBERED -- UNABLE TO CONTINUE'
MSG1     TEXTC    'REBOOT FROM RAD FOR FILE SAVE ONLY'
         PAGE
COCMES   EQU      %                 RESTORE COC MESSAGE
         SH,2     3,1
         LI,7     16
         LW,5     *BUFLN,2
         STW,5    COCMESS-1,7
         AI,R2    1
         BDR,7    %-3
         SH,2     3,1
         AI,R2    -1                POINT TO NEXT CONTROL WORD
         B        RETURN
         DO       CNM
         SREF     MODE5,LNOL
         REF      X80
COCRES   SH,2     3,1
         LI,7     LNOL-1
COCRES10 LW,5     *BUFLN,2
         AI,2     1
         LB,6     MODE5,7
         AND,5    X80
         OR,6     5
         STB,6    MODE5,7
         AI,7     -1
         BGEZ     COCRES10
         AI,2     -1
         SH,2     3,1
         B        RETURN
         FIN
**
**
RCVDMP   EQU      %                 MOVE RECOVERY DUMP TO FILE
         SH,2     3,1
         LW,5    *BUFLN,2
         STW,5    RCVRAD            START DA
         AI,2     1
         LW,5    *BUFLN,2
         STW,5    RCVEND            END DA + 1 GRAN
**   GET A VIRTUAL PAGE FOR BUFFER
         M:GVP    P:JIT
         BCS,8    NORCV
         CAL1,1   OPN:MON           OPEN RAD FILE
MOVEDMP  LI,3     512*4
         LW,8     RCVRAD
         LW,4     BUF
         BAL,11   RDDISK1
         B        NORCV
,LL      M:WRITE  MONDMP,(BUF,*BUF),(SIZE,512*4),(ERR,ERR),;
                  (ABN,ABN),(KEY,KEYLOC),(ONEWKEY)
         MTW,1    KEYLOC            KEY WITH PAGE NO.
         BAL,11   INCRDA
         LW,5     RCVRAD
         CW,5     RCVEND
         BNE      MOVEDMP
         M:CLOSE  MONDMP,(SAVE)
         AI,R2    -2                POINT TO NEXT CONTROL WORD
         B        RETURN
**
**
TPDMP    EQU      %
         AI,2     -2
         B        RETURN
         PAGE
SYMFR    EQU      %                 RESTORE SYMFILES
         AI,2     -1
         LW,5     *BUFLN,2
         STW,5    SGB
         AI,2     -1
         LW,5     *BUFLN,2
         BEZ      SYM1L
SYM2L    AI,2     -1
         LW,4     *BUFLN,2
         LB,7     4,1
         STB,4    SSIG,7
         BDR,5    SYM2L
SYM1L    EQU      %
         AI,2     -1
         B        RETURN
**
**
ACT      EQU      %                 READ JITS, ACCOUNT, MONDMP
         LH,R7    R3,R1             NUMBER OF JITS TO PROCEES
         MTW,0    RCVEND            MONDMP TO BE PRODUCED
         BEZ      NO:OPN
         CAL1,1   OPN:MON           OPEN MONDMP IN INOUT
NO:OPN   EQU      %
         M:OPEN   M:EI,(FILE,':RATE'),(ERR,RATER),(ABN,RATER)
         M:READ    M:EI,(BUF,RECORD),(SIZE,72*4),;
                  (ERR,RATER),(ABN,RATER)
         M:CLOSE   M:EI,(SAVE)
         LI,0     0
         B        RATER+1
RATER    LI,0     X'FF'
         STW,0    RATEFLAG
JITLP    LI,5     1                 BYTE POSITION FOR USER NO. IN JIT KEY
         AI,2      -1
         LW,8      *BUFLN,2
         LB,3      8                USER NO.
         STB,3     JITKEY,5
         LI,0     0
         STB,0    8                 CLEAR USER NO.
         M:GVP    P:JIT
         LW,4      BUF
         LI,3      512*4
         STW,7    TMP2
         BAL,11   NICOLE
         B        NOAMR             BAD JIT ADDRESS-SKIP THIS USER
         LW,11    RCVEND
         BEZ      NO:DMP            NO RAD DUMP
         M:WRITE  MONDMP,(BUF,*BUF),(SIZE,512*4),;
                  (KEY,JITKEY),(NEWKEY),;
                  (ERR,ERR),(ABN,ABN)
NO:DMP   EQU      %
         LI,1     1
         LW,R5    P:JIT+TSTACK-JIT  TOP OF STACK
         SH,R5    P:JIT+TSTACK+1-JIT,R1  WORD COUNT
         AND,5    =X'1FFFF'
         CI,5     TSTACK+1
         BNE      NOAMR             BAD JIT - SKIP THIS USER
         LC       P:JIT             GHOST JOB
         BCS,4    NOAMR             YES-SKIP GHOST JOBS(AMR NOT RELEASED)
         BCS,8    NO:IDMS           NO ACCOUNTING SUMMARY FOR ONLINE
         LH,SR1   RCVCODE
         CI,SR1   X'89'             CRASH CODE .89
         BE       NOAMR             YES-DONT RELEASE GRANULES AFTER HGP RECON
         M:DEVICE M:LL,PAGE         TOP THE PAGE
         LCI      5
         LM,R4    P:JIT+JACCN       GET ACCOUNT,NAME
         LCI      2
         STM,R4   LPMSG+5           PUT ACCOUNT INTO MESSAGE
         LCI      3
         STM,R6   LPMSG+1           PUT NAME INTO MESSAGE
         M:PRINT  (MESS,LPMSG)      PRINT NAME, ACCT.(SYMBIONT)
NO:IDMS  EQU      %
         LW,SR1   P:JIT+J:AMR-JIT   DA OF ASSIGN MERGE RECORD
         BEZ      NOAMR             NO ASSIGN MERGE RECORD
         BAL,SR4  CHKDA             GO-CHECK DA
         BCR,15   NOAMR             BAD DA DONT GO TO ACCNTSUM
         BAL,11   ACCNTSUM          DO ACCOUNTING
         LW,8     P:JIT+J:AMR-JIT
         BEZ      NOAMR             NO ASSIGN MERGE RECORD
         BAL,11   CHKDA             CHECK IT
         BCR,15   NOAMR             BAD, DON'T RELEASE
         PUSH     2,1
         BAL,11   RBG               GOOD, RELEASE IT
         PULL     2,1
NOAMR    EQU      %
         LW,R7    TMP2              RESTORE NUMBER OF JITS
         BDR,7    JITLP
         AI,2     -1
         M:FVP    P:JIT
         LW,11    RCVEND
         BEZ      RETURN
         M:CLOSE  MONDMP,(SAVE)
         B        RETURN
         PAGE
ERR      EQU      %
ABN      EQU      %
         SLS,SR3  -17
         CI,SR3   X'300'**-1        FILE NOT THERE
         BNE      *SR1              NO-ERROR
         LW,R3    SR1               SAVE RETURN
         LI,SR1   2
         STW,SR1  MODE              SET OUT MODE
         CAL1,1   OPN:MON           OPEN MONDUMP
         LI,SR1   4
         STW,SR1  MODE              SET UPDATE MODE
         B        *R3               RETURN TO CAL+1
**
**
INCRDA   EQU      %
         MTW,2    RCVRAD            BUMP RECOVER RAD ADDRESS
         B        *11               RETURN
         PAGE
TYOUT    EQU      %                 TYPE MESSAGE ON OPERATOR CONSOLE
         M:TYPE   (MESS,*4)
         B        *11               RETURN
**
**
COCOUT  EQU     %       SEND MESSAGE TO ALL TERMINALS
         LI,12    COC               SEE IF NON-COC SYSTEM
         BEZ      *11               B/NO COC
         PUSH     3,1
         LI,1     0
COCOUT0  EQU      %
         AI,1     1
         LI,R6    LCOC+1            NUMBER OF COCS
COCOUT1  LI,D1    X'F0'
         AND,D1   CO:STAT-1,R6      DIO ADDRESS
         AI,D1    X'3005'           TRANSMIT DATA FUNCTION
         LD,R2    COD:LPC-2,R6      LOGICAL LINE RANGE THIS COC
COCOUT2  LW,SR2   R3                HIGHEST LOGICAL LINE THIS COC
         SW,SR2   R2                PHYSICAL LINE THIS COC
         LB,R5    COCTERM,R3        TRANSLATE TABLE INDEX
         LH,SR1   COCOTV,R5         TRANSLATE TABLE ADDRESS
         LB,R7    *R4,R1            EBCDIC CHAR
         LC       MODE2,R3          2741 TYPE TERMINAL
         BCS,1    2741TRNS          YES-TRANSLATE FOR 2741
         LB,R7    ASCII,R7          NO-TRANSLATE INTO ASCII WITH PARITY
COCOUT5  SLS,R7   8
         AW,R7    SR2               PUT IN PHYSICAL LINE NUMBER
         WD,R7    *D1               TRANSMIT CHAR
COCOUT4  AI,R3    -1                DEC LOGICAL LINE NUMBER
         CW,R3    R2                MORE LOGICAL LINES THIS COC
         BGE      COCOUT2           YES-TRANSMIT TO ALL LINES THIS COC
         BDR,R6   COCOUT1           TRANSMIT TO ALL COCS
         LI,2     72000             DELAY
         BDR,2    %
         CB,1     *4
         BL       COCOUT0           ARE WE DONE
         LI,R6    LCOC+1            L/# OF COCS
COCOUT3  LI,D1    X'F0'             L/MASK FOR DIO ADR
         AND,D1   CO:STAT-1,R6      G/DIO ADR
         AI,D1    X'300E'           STOP TRANSMIT FUNCTION
         LI,R3    63                L/MAX LINE# ON A COC
         WD,R3    *D1               STOP TRANSMIT
         BDR,R3   %-1               BDR/PROCESS NEXT LINE
         WD,R3    *D1               STOP TRANSMIT ON LINE 0
         BDR,R6   COCOUT3           BDR/PROCESS NEXT COC
         PULL     3,1
         B        *11               RETURN
**
2741TRNS CI,R7    X'0D'             CR
         BNE      %+3               NO
         LI,R7    X'6D'             YES-TRANSMIT X'6D'
         B        COCOUT5
         CI,R7    X'15'             LF
         BNE      %+3               NO
         LI,R7    X'1C'             YES-TRANSMIT X'1C'
         B        COCOUT5
         AND,SR1  =X'FFFF'
         CI,SR1   X'4000'           TRANSLATE TABLE ADDRESS LEGAL
         BGE      COCOUT4           NO-SKIP TRANSMITTING CHAR
         LB,R7    *SR1,R7           YES-TRANSLATE USING CORRECT TABLE
         AND,R7   =X'3F'            TAKE OFF ANY CONTROL BITS
         SCS,R7   32
         BOD      %+2
         AI,R7    X'40'             MAKE ODD PARITY
         B        COCOUT5
**
CR       EQU      '
'               CARRIAGE RETURN CHARACTER
LF       EQU      '
'               LINE FEED CHARACTER
TC       EQU      ' '               TIMING CHARACTER; RUBOUT
TCS      EQU      TC,TC,TC,TC,TC,TC,TC,TC    TIMING CHARACTERS
BELL     EQU      ' '               BELL
HGPERRUM TEXTC    CR,LF,TCS,'STAND BY - FOR EXTENDED RECOVERY',CR,LF
**
**
ASCII    EQU      %                 EBCDIC --> ASCII CONVERSION TABLE
         DATA     X'818203',X'84090687',X'8805958B',X'C8D8E0F'
         DATA     X'90111293',X'140A9617',X'18999A1B',X'9C1D1E9F'
         DATA     0,X'A0000',0,0
         DATA     0,0,0,0
         DATA     X'A0000000',0,X'5C2E',X'3C282BDB'
         DATA     X'A6000000',0,X'2124',X'AAA9BBDD'
         DATA     X'2DAF0000',0,X'DEAC',X'A55FBE3F'
         DATA     0,0,X'3AA3',X'C027BD22'
         DATA     X'4142C3',X'44C5C647',X'48C90000',0
         DATA     X'CA4BCC',X'4D4ECF50',X'D1D20000',0
         DATA     X'53D4',X'5556D7D8',X'595A0000',0
         DATA     0,0,0,0
         DATA     X'4142C3',X'44C5C647',X'48C90000',0
         DATA     X'CA4BCC',X'4D4ECF50',X'D1D20000',0
         DATA     X'53D4',X'5556D7D8',X'595A0000',0
         DATA     X'30B1B233',X'B43536B7',X'B8390000',X'FF'
         PAGE
         PAGE
NICOLE   EQU      %
         MTW,0    S:DP
         BEZ      RDRAD1
         LB,7     8
         SLS,8    -8
         STB,8    UB:C#,7
         LI,8     1
         B        RDUSR1            READ DP
         PAGE
         PAGE
**
*                                   SGCBUF PLUS RECOVER GENERATED ENTRYS
SGCBUF   EQU      %
         SH,R2    R3,R1             INDEX TO FIRST WORD IN ENTRY
         PUSH     R2
         AW,R2    BUFLN             ADDRESS OF FIRST WORD IN ENTRY
         LH,R4    R3,R1             SIZE OF SYMB COMM BUFF
         CAL1,8   GET:DY            GO-GET BUFFER
         STW,SR2  SGCPAGE           ADDRESS OF SYMB GHOST BUF
         AW,R2    R4
         AWM,R4   SGCPAGE
         LCW,R4   R4
         LW,R5    *R2,R4
         STW,R5   *SGCPAGE,R4
         BIR,R4   %-2               COPY SGCBUF TO BUFFER
         LH,R7    R3,R1
         SLS,R7   2                 BYTE SIZE OF SYMB GHOST COMM BUF
         LI,SR1   4                 INOUT MODE
         CAL1,1   OPNSYMBG          OPEN SYMB GHOST COMM FILE
         CAL1,1   OPN:MON           OPEN MONDUMP
         LI,SR1   TXCSGCM           KEY FOR SYMB GHOST COMM BUF
         CAL1,1   WRSYMBG           WRITE SYMB GHOST COMM RECORD
         M:WRITE  MONDMP,(ERR,ERR),(ABN,ABN),(BUF,*SR2),(SIZE,*R7),;
                  (KEY,*SR1),(BTD,0),ONEWKEY,WAIT
         CAL1,1   CLSSYMBG          CLOSE SYMB GHOST COMM FILE
         M:CLOSE  MONDMP,SAVE       ALSO IN MONDUMP
         M:FP     1                 GIVE BACK BUFFER PAGE
         LW,R3    =X'05010001'      HOF,TOU,0,HOU
         LI,R4    RCVRGFC
         LCI      2
         STM,R3   SGCHD             INITIALIZE SGCHD FOR SYMB GHOST
         PULL     R2
         AI,R2    -1                INDEX TO NEXT CODE WORD
         B        RETURN
         PAGE
SGABN    EQU      %
         SLS,SR3  -17
         CI,SR3   X'300'**-1        CREATE NEW SYMB RECOVERY FILE
         BNE      *SR1              NO-ERROR
         LW,R3    SR1               SAVE RETURN ADDRESS
         LI,SR1   2                 OUT MODE
         CAL1,1   OPNSYMBG          OPEN OUT MODE
         B        *R3               RETURN
SGERR    EQU      %
         B        *SR1
         PAGE
OPNSYMBG GEN,8,7,17 X'14',0,M:EO    OPEN :RBBRVR.:SYS
         DATA     X'CF480009'
         DATA     SGERR             ERROR
         DATA     SGABN             ABNORMAL
         DATA     10                RE-TRY
         DATA     2                 KEYED
         DATA     2                 DIRECT
         PZE      *SR1              MODE
         DATA     2                 SAVE
         DATA     7                 KEYM
         DATA     X'01000202'
         TEXTC    ':RBBRVR'
         DATA     X'02010202'
         TEXT     ':SYS    '
WRSYMBG  GEN,8,7,17 X'11',0,M:EO    WRITE :RBBRVR.:SYS
         DATA     X'FC000050'
         DATA     SGERR             ERROR
         DATA     SGABN             ABNORMAL
         PZE      *SR2              BUFFER
         PZE      *R7               SIZE
         PZE      *SR1              KEY
         DATA     0                 BTD
CLSSYMBG GEN,8,7,17 X'15',0,M:EO    CLOSE !RBBRVR.:SYS
         DATA     X'80000000'
         DATA     2                 SAVE
TXCSGCM  TEXTC    'RBBATCM'         KEY FOR COMMICATION BUF RECORD
         PAGE
**
**
DATA     DSECT    0
P:JIT    EQU      X'1B000'
BUF      PZE      P:JIT
OPN:MON  GEN,8,24 X'14',MONDMP      OPEN OUTPUT FILE
         DATA     X'FF480001'
         PZE      ERR
         PZE      ABN
         PZE      *BUF
         PZE      512*4             1 PAGE RECORD SIZE
         PZE      10                MAX TRIES
         PZE      2                 KEYED
         PZE      2                 DIRECT
MODE     DATA     4                 INOUT MODE
         PZE      2                 SAVE
         DATA     7                 MAX KEY LENGTH
         DATA     X'01000202'
DMPNAME  TEXTC    'MONDMP0'
         DATA     X'04010202'
         TEXT     ' 00100  '        EXPIRE 1 DAY HENCE
**
**
GET:DY   GEN,8,24 X'08',1
RCVXT    PZE
BUFLN    PZE      0
RCVEND   DATA     0
GET:CM   GEN,8,24 X'0C',2           GET 2 COMMON PAGES
MAPFLG   DATA     X'FF'             GHOST1 ALWAYS MAPED
LPMSG    TEXTC    '   NAMENAMENAME,   ACCOUNT'
TMP2     PZE
TMP1     DATA      0
KEYLOC   GEN,8,24 X'3',0
JITKEY   GEN,8,24  X'03',0          BYTE 2 IS USER NO.
SGCPAGE  DATA     0                 ADDRESS OF SYMBIONT GHOST COM. BUF.
         END

