window:
	res:
		windowType	wstandard
	endres:
endwindow:
close:
	res:
		bitmapPath	$(bitmaps)
		bitmapFile	CLOSE::CBM
	endres:
endclose:
title:
	res:
		leftLabel		'Password Setup'
		leftKanjiFont		$(kanjiFont)
		leftFont		$(kanaFont)
		switch $(COLOR)
			case MONO:
				bitmapPath	$(bitmaps)
				backgroundFile	GRAY3
				transparent	false
				break
		endswitch
	endres:
endtitle:
dialog: dialogs
	res:
		defaultDistance		#(fWidth)
		dialogType		modeless
		defaultButton		ok
	endres:
	ditem: msg
		res:
			itemType	bitmap
			label		'Enter password                      '
			kanjiFont	$(kanjiFont)
			font		$(kanaFont)
			vertDistance	10
			horizDistance	10
		endres:
	endditem:
	ditem: passwd_cover
		res:
			itemType	bitmap
			fromVert	msg
			leftLabel	'        '
			borderWidth	2
			border		black
			vertDistance	#(fWidth)
			horizDistance	#(fWidth)*2
			height		#(fHeight)+4
			leftKanjiFont	$(kanjiFont)
			leftFont	$(kanaFont)
		endres:
	endditem:
	ditem: passwd
		res:
			itemType	text
			fromVert	msg
			vertDistance	#(fWidth)
			horizDistance	#(fWidth)*2
			length		8
			height		#(fHeight)
			width		#(fWidth)*8+4
			kanjiFont	$(kanjiFont)
			font		$(kanaFont)
			shadowWidth	0
			focus
			bind		getchar
		endres:
		act:
			put $(passwd)
		endact:
	endditem:
	ditem: ok
		res:
			itemType	button
			fromVert	msg
			fromHoriz	passwd
			label		' O K '
			kanjiFont	$(kanjiFont)
			font		$(kanaFont)
			vertDistance	#(fWidth)
			horizDistance	#(fWidth)*2
		endres:
		act:
			switch #(step)
				case 1:
					setval title leftLabel 'Confirm Password'
					setval msg label 'To confirm, re-enter password again.'
					put $(passwd) $(newpasswd)
					put '' $(passwd)
					setval passwd string $(passwd)
					job getchar
					buzzer
					put 2 $(step)
					break
				case 2:
					$(bin)/Spwd_check -u root -s $(newpasswd) $(passwd) 2> /dev/null
					switch #(status)
						case 0:
							put on $(PASSWD_SET)
							put $(passwd) $(PASSWD)
							close
							break
						default:
							put 10 $(err)
							put 'Password mismatched.' $(confirm_msg1)
							put 'Do you retry ?' $(confirm_msg2)
							$(err) = sub $(commonPath)/yesno2 ++48++48
							buzzer
							trap $(err) retry
							break
					endswitch
					break
			endswitch
		endact:
	endditem:
enddialog:
proc: pre
	put off $(PASSWD_SET)
	switch $(allset)
		case on:
		case off:
			put off $(PASSWD_SET)
			break
	endswitch
	put 0 $(menu_no)
endproc:
proc: close
	job pre
	close
endproc:
proc: off
	switch #(menu_no)
		case 10:
			close $(err)
			break
	endswitch
endproc:
proc: open
	setval passwd string ''
	setval passwd_cover leftLabel '?       '
	setval title leftLabel 'Password Setup'
	setval msg label 'Enter password                      '
	put 1 $(step)
	put 0 $(menu_no)
	setval ok sensitive false
endproc:
proc: retry
	switch $(answer)
		case ok:
			job open
			buzzer
			break
		case cancel:
			put next $(PASSWD_SET)
			close
			break
	endswitch
endproc:
proc: getchar
	varlen $(passwd)
	switch #(status)
		case 0:
			put '?' $(str)
			setval ok sensitive false
			break
		case 1:
			put '#?' $(str)
			setval ok sensitive true
			break
		case 2:
			put '##?' $(str)
			break
		case 3:
			put '###?' $(str)
			break
		case 4:
			put '####?' $(str)
			break
		case 5:
			put '#####?' $(str)
			break
		case 6:
			put '######?' $(str)
			break
		case 7:
			put '#######?' $(str)
			break
		case 8:
			put '########' $(str)
			break
	endswitch
	setval passwd_cover leftLabel $(str)
endproc:
proc: unmap
	switch #(menu_no)
		case 10:
			unmap $(err)
			break
	endswitch
endproc:
proc: map
	switch #(menu_no)
		case 10:
			move $(err)
			raise $(err)
			map $(err)
			break
	endswitch
endproc:
proc: title
	job move
	job up
endproc:
proc: raise
	job up
endproc:
proc: move
	switch #(menu_no)
		case 10:
			move $(err)
			break
	endswitch
endproc:
proc: up
	switch #(menu_no)
		case 10:
			raise $(err)
			break
	endswitch
endproc:
