#! /bin/csh
# $Header: dailystatsmain,v 4.300 91/06/09 00:59:29 root Rel41 $
#	Copyright 1990 Sony Corp.
#	Copyright 1990 Performance Systems International Inc.
#       copyright 1988 NYSERNet, Inc.
#	All Rights Reserved.

# called by dailysnmp

source ../../config/report-env
if (-e $ROOT/config/daily-env) then
  source $ROOT/config/daily-env
else
  echo "$0 : daily-env missing. Can't continue. Exit."
  exit(1)
endif

if ($#argv >= 1) then
	set ext=$argv[1]
else
  echo "Usage : $0 mmddyy"
  exit(1)
endif

if (! $?DAILYREPORTS) then
 set	DIR	= $ROOT/daily/report/$ext
else
  set	DIR	= $DAILYREPORTS/$ext
endif
set	DAILY	= $DIR/Daily.Stats
set	TRAP1	= /tmp/trap.1.$$.$ext
set	EGP	= $DIR/EgpLoss
set     REBOOTS	= $DIR/Reboots
set 	LINKDOWN = $DIR/LinkDowns
set     Date = `$BIN/prsdate $ext`

/bin/rm -f $DAILY $TRAP1 $EGP $REBOOTS $LINKDOWN

$BIN/dailystats $ext >! $DAILY

# Now we are going to process the trap data.
# Preprocessing step

awk -f $SEDAWK/traps.1.awk	$DATA/$ext/$TRAPLOG:t >! $TRAP1

awk -f $SEDAWK/traps.2.egp.awk	$TRAP1 | sort | \
	awk -f $SEDAWK/traps.3.egp.awk >! $EGP

sort $TRAP1 | awk -f $SEDAWK/traps.2.boot.awk >! $REBOOTS

grep Link $TRAP1 | sort | sed 's/:/ /g' | \
	awk -f $SEDAWK/traps.2.link.awk | sort +0 -3 >! $LINKDOWN

$BIN/tops $ext

/bin/rm $TRAP1
